1. STEP-MXO2第一代

1. 掌握PWM的原理
2. 了解LED通过PWM调亮度的方法
3. 基于STEP-MXO2第一代平台实现周期为2s的呼吸灯设计

呼吸灯：顾名思义，灯光的亮度在控制下不断的在亮和灭之间逐渐变化，感觉好像是人在呼吸。控制LED的亮度总体有两种方法，一种是给LED灯上施加模拟信号（可以串接可调电阻或DAC输出模拟信号），通过改变流经LED上的电流控制LED灯的亮度；另一种是使用PWM，给LED灯上施加数字信号，通过调整数字信号的占空比（调整占空比 = 调整有效值）来控制LED灯的亮度。这里我们的呼吸灯就是采用第二种PWM的方法实现。

PWM脉冲宽度调制，是利用数字输出对模拟电路进行控制的一种非常有效的技术。通过改变PWM的占空比从而改变输出电平的有效值，在LED的亮度上反应出来，如果占空比能够由小变大再变小，在LED上反应出的效果就是呼吸灯的效果。

如上图所示，脉冲信号的周期为T，高电平脉冲宽度为t，占空比为t/T。为了实现PWM脉宽调制，我们需要保持周期T不变，调整高电平脉宽t的时间，从而改变占空比。

• 当t = 0时，占空比为0%，因为我们的LED硬件为低电平点亮，所以为最亮的状态。
• 当t = T时，占空比为100%，LED灯为最暗（熄灭）的状态。

结合呼吸灯的原理，整个呼吸的周期为最亮→最暗→最亮的时间，即t的值的变化：0→T→0逐渐变化，这个时间应该为2s

呼吸灯的设计较为简单，我们使用25MHz的系统时钟作为高频信号做分频处理，调整占空比实现PWM，通过LED灯LD1指示输出状态。

呼吸灯设计要求呼吸的周期为2s，也就是说LED灯从最亮的状态开始，第一秒时间内逐渐变暗，第二秒的时间内再逐渐变亮，依次进行。

本设计中需要两个计数器cnt1和cnt2，cnt1随系统时钟同步计数（系统时钟上升沿时cnt1自加1）范围为0~T，cnt2随cnt1的周期同步计数（cnt1等于T时，cnt2自加1）范围也是0~T，这样每次cnt1在0~T的计数时，cnt2为一个固定值，相邻cnt1计数周期对应的cnt2的值逐渐增大，我们将cnt1计数0~T的时间作为脉冲周期，cnt2的值作为脉冲宽度，则占空比 = cnt2/T,占空比从0%到100%的时间 = cnt2*cnt1 = T^2 = 1s = 25M个系统时钟，T = 5000，我们定义CNT_NUM = 5000作为两个计数器的计数最大值。

parameter	CNT_NUM = 5000	//period = (5000^2)*2 = 50000000 = 2s

计数器cnt1随系统时钟从0~（CNT_NUM-1）循环计数，如下

//generate cnt1 signal
always@(posedge clk_in or negedge rst_n_in) begin 
	if(!rst_n_in) begin
		cnt1<=13'd0;
	end else begin
		if(cnt1>=CNT_NUM-1) cnt1<=1'b0;
		else cnt1<=cnt1+1'b1;
	end
end

计数器cnt2随cnt1的周期从0~（CNT_NUM-1）循环计数，如下

//generate cnt2 signal
always@(posedge clk_in or negedge rst_n_in) begin 
	if(!rst_n_in) begin
		cnt2<=13'd0;
		flag<=1'b0;
	end else begin
		if(cnt1==CNT_NUM-1) begin
			if(!flag) begin
				if(cnt2>=CNT_NUM-1) flag<=1'b1;
				else cnt2<=cnt2+1'b1;
			end else begin
				if(cnt2<=0) flag<=1'b0;
				else cnt2<=cnt2-1'b1;
			end
		end else cnt2<=cnt2;
	end
end

最后将两个计数器cnt1和cnt2比较，输出呼吸灯控制信号：

//Compare cnt1 and cnt2, generate PWM-Breath-led
assign	Breath_led = (cnt1<cnt2)?1'b0:1'b1;

引脚分配如下：

• 呼吸灯原理
• PWM脉宽调节
• 脉冲发生原理

• 脉冲发生器
• Lattice MachXO2数据手册

代码附件 - 呼吸灯verilog代码

// --------------------------------------------------------------------
// >>>>>>>>>>>>>>>>>>>>>>>>> COPYRIGHT NOTICE <<<<<<<<<<<<<<<<<<<<<<<<<
// --------------------------------------------------------------------
// Module: Breath_led
// 
// Author: Step
// 
// Description: PWM-Breath_led
// 
// Web: www.ecbcamp.com
//
// --------------------------------------------------------------------
// Code Revision History :
// --------------------------------------------------------------------
// Version: |Mod. Date:   |Changes Made:
// V1.0     |2015/11/11   |Initial ver
// --------------------------------------------------------------------
module Breath_led #
(
parameter	CNT_NUM = 5000	//period = (5000^2)*2 = 50000000 = 2s
)
(
input		clk_in,			//system clk
input		rst_n_in,			//system reset
output		Breath_led		//Breath led output
);
 
reg	[12:0]	cnt1;
//generate cnt1 signal
always@(posedge clk_in or negedge rst_n_in) begin 
	if(!rst_n_in) begin
		cnt1<=13'd0;
	end else begin
		if(cnt1>=CNT_NUM-1) cnt1<=1'b0;
		else cnt1<=cnt1+1'b1;
	end
end
 
reg	flag;
reg	[12:0]	cnt2;
//generate cnt2 signal
always@(posedge clk_in or negedge rst_n_in) begin 
	if(!rst_n_in) begin
		cnt2<=13'd0;
		flag<=1'b0;
	end else begin
		if(cnt1==CNT_NUM-1) begin
			if(!flag) begin
				if(cnt2>=CNT_NUM-1) flag<=1'b1;
				else cnt2<=cnt2+1'b1;
			end else begin
				if(cnt2<=0) flag<=1'b0;
				else cnt2<=cnt2-1'b1;
			end
		end else cnt2<=cnt2;
	end
end
 
//Compare cnt1 and cnt2, generate PWM-Breath-led
assign	Breath_led = (cnt1<cnt2)?1'b0:1'b1;
 
endmodule
 

代码附件：呼吸灯测试代码

// --------------------------------------------------------------------
// >>>>>>>>>>>>>>>>>>>>>>>>> COPYRIGHT NOTICE <<<<<<<<<<<<<<<<<<<<<<<<<
// --------------------------------------------------------------------
// Module: Breath_led_test
// 
// Author: Step
// 
// Description: Testbench for Water_led
// 
// Web: www.ecbcamp.com
// 
// --------------------------------------------------------------------
// Code Revision History :
// --------------------------------------------------------------------
// Version: |Mod. Date:   |Changes Made:
// V1.0     |2015/11/11   |Initial ver
// --------------------------------------------------------------------
`timescale 1ns / 100ps
module Breath_led_test;
 
parameter CLK_PERIOD = 40;  //CLK_PERIOD=40ns, Frequency=25MHz
parameter CNT_NUM = 6;
 
reg sys_clk;
initial
	sys_clk = 1'b0;
always
	sys_clk = #(CLK_PERIOD/2) ~sys_clk;
 
reg sys_rst_n;  //active low
initial 
	begin
		sys_rst_n = 1'b0;
		#100;
		sys_rst_n = 1'b1;
	end
 
wire Breath_led;
Breath_led #(.CNT_NUM(CNT_NUM))
Breath_led_uut
(
.clk_in(sys_clk),
.rst_n_in(sys_rst_n),
.Breath_led(Breath_led)
);
 
endmodule